home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 105 - PROSEL - 3.3.5 S2.B.dsk / INSTALL.REVISN.bas < prev    next >
BASIC Source File  |  2019-02-17  |  5KB  |  118 lines
  1. 1  REM INSTALL PROSEL REVISION
  2. 2  REM 
  3. 3  REM Run under BASIC 1.1.
  4. 4  REM Must be room for 2 more files on main dir.
  5. 5  REM 
  6. 10  IF  PEEK(176) >30  THEN  STOP 
  7. 20  IF  PEEK(34)  THEN 60
  8. 30  PRINT  CHR$(4)"PR#3"
  9. 40  PRINT  CHR$(12);
  10. 50  PRINT  TAB( 25)"ProSel revision installation": POKE 34,4
  11. 60  PRINT  CHR$(4)"BLOAD/FLOPPY/COMMANDS/COPY,TCMD,A$4000": CALL 4 *4096
  12. 70  LOMEM: 6 *4096:DE$ = "DELETE":D$ =  CHR$(4):C$ = "COPY":U$ = "UNLOCK"
  13. 80 VOL$ = "/FLOPPY/":F$ = VOL$:P$ = "PROSEL":PS$ = "PROSEL.SYSTEM":V =  PEEK(48944)
  14. 90  PRINT : HOME : PRINT "This program is for replacing an existing copy of "P$" while keeping your"
  15. 100  PRINT "present application list.  It will backup the present "P$" file and then"
  16. 110  PRINT "delete the original.  Type "; CHR$(34);"OK"; CHR$(34);" <RTN> to continue, anything else to abort."
  17. 120  GOSUB 8000
  18. 130  INPUT PF$: IF PF$ < >"OK"  AND PF$ < >"ok"  THEN  TEXT : PRINT : HOME : PRINT D$"-STARTUP"
  19. 140 PF$ = "/HARD1/"
  20. 150  PRINT : PRINT "If the volume containing "P$" is named "PF$" then press RETURN."
  21. 160  PRINT "Otherwise type the volume name";: INPUT ": ";N$
  22. 170  IF N$ = ""  THEN 210
  23. 180  IF  LEFT$(N$,1) < >"/"  THEN N$ = "/" +N$
  24. 190  IF  RIGHT$(N$,1) < >"/"  THEN N$ = N$ +"/"
  25. 200 PF$ = N$
  26. 210  PRINT : INPUT "Install 40 or 80 column or Videoterm version? (40/80/VT):";V$
  27. 220  IF V$ < >"40"  AND V$ < >"80"  AND V$ < >"VT"  AND V$ < >"vt"  THEN 210
  28. 230  PRINT : INPUT "Time delay before screen blanking in ProSel in minutes (2-59) :";TD
  29. 240  IF TD <2  OR TD >59  THEN 230
  30. 250  ONERR  GOTO 1000
  31. 260  PRINT D$"VERIFY"PF$
  32. 270  IF V =  PEEK(48944)  THEN 4800
  33. 280  ONERR  GOTO 3000
  34. 290  PRINT D$U$PF$P$
  35. 300  PRINT D$U$PF$PS$
  36. 310  PRINT D$"BLOAD"PF$PS$",TSYS,A$4000"
  37. 320  PRINT D$C$PF$PS$","PF$PS$".B"
  38. 330  ONERR  GOTO 2000
  39. 340  PRINT D$C$VOL$PS$","PF$PS$
  40. 350 LOC = 4 *4096 +3: IF  PEEK(LOC) < >238  OR  PEEK(LOC +1) < >238  THEN 400
  41. 360 LOC = 4 *4096 +6:NL = 2 *4096 +6:L =  PEEK(LOC): IF   NOT L  THEN 400
  42. 370  PRINT D$"BLOAD"PF$PS$",TSYS,A$2000"
  43. 380  FOR I = 0 TO L: POKE NL +I, PEEK(LOC +I): NEXT I
  44. 390  PRINT D$"BSAVE"PF$PS$",TSYS,B0,A$2000"
  45. 400  GOSUB 7000
  46. 410  PRINT D$"RENAME"PF$P$","PF$P$".";V +1
  47. 420  GOSUB 7000
  48. 430  FOR Q = 1 TO V:Q$ = P$ +"." + STR$(Q)
  49. 440  ONERR  GOTO 4500
  50. 450  PRINT D$U$PF$Q$
  51. 460  PRINT D$C$PF$Q$","PF$Q$".BAK"
  52. 470  PRINT D$DE$PF$Q$
  53. 480  PRINT D$C$F$P$"."V$","PF$Q$
  54. 490  PRINT D$"BLOAD"PF$Q$".BAK,A$2000"
  55. 500  PRINT D$"BLOAD"PF$Q$",A$4000"
  56. 510  IF Q = 1  THEN  PRINT : PRINT  TAB( 30)"DO NOT INTERRUPT!": PRINT 
  57. 520 AD = 2 *4096
  58. 530  IF V >1  THEN  PRINT  TAB( 30)"Revising "Q$
  59. 540  IF  PEEK(AD) < >76  OR  PEEK(AD +1) >9  THEN 4000
  60. 550  IF  PEEK(AD +2) < >10  AND  PEEK(AD +2) < >8  THEN 4000
  61. 560  IF  PEEK(AD +5) < >255  AND  PEEK(AD +5) < >223  THEN 4000
  62. 570 AD = AD + PEEK(AD +3) +256 * PEEK(AD +4)
  63. 580  IF  PEEK(AD) <128  THEN 4000
  64. 590  CALL 7936: POKE 4 *4096 +6,TD
  65. 600  PRINT D$"BSAVE"PF$Q$",B0,A$4000,L$1800"
  66. 610  PRINT D$DE$PF$Q$".BAK"
  67. 620  NEXT Q
  68. 630 Q$ = P$: PRINT D$"RENAME"PF$P$".1,"PF$P$
  69. 640  GOSUB 6050
  70. 650  TEXT : HOME : PRINT D$"-"PF$PS$
  71. 660  STOP 
  72. 1000  PRINT : PRINT "Volume "PF$" not found - installation aborted."
  73. 1010  GOTO 5000
  74. 2000  GOSUB 6000
  75. 3000  HOME 
  76. 3010  PRINT "Cannot find "P$" on "PF$".  You must rerun this program and select"
  77. 3020  PRINT  CHR$(34)"new installation." CHR$(34)
  78. 3030  GOTO 5000
  79. 4000  HOME : GOSUB 6000
  80. 4010  PRINT "The copy of "P$" on the receiving disk is not supported by this program."
  81. 4020  PRINT "Delete all "P$" related files on the receiving disk, reboot the "P$" disk,"
  82. 4030  PRINT "and select the option to install a new "P$" system."
  83. 4040  GOTO 5000
  84. 4500  GOSUB 6000
  85. 4501  PRINT "Disk error occurred.  ";
  86. 4510  GOTO 4900
  87. 4800  PRINT : PRINT "Cannot install on volume named "VOL$".  ";
  88. 4900  PRINT "Installation aborted."
  89. 5000  TEXT : VTAB 22: NEW 
  90. 5010  END 
  91. 6000  ONERR  GOTO 6090
  92. 6010  PRINT D$DE$PF$PS$
  93. 6020  PRINT D$C$PF$PS$".B,"PF$PS$
  94. 6030  PRINT D$DE$PF$P$
  95. 6040  PRINT D$C$PF$Q$".BAK,"PF$P$
  96. 6050  ONERR  GOTO 6090
  97. 6060  PRINT D$DE$PF$PS$".B"
  98. 6070  PRINT D$DE$PF$Q$".BAK"
  99. 6080  POKE 216,0: RETURN 
  100. 6090  POKE 216,0: CALL 62248: RETURN 
  101. 7000 V = 1: ONERR  GOTO 7030
  102. 7010  PRINT D$"VERIFY"PF$P$".";V
  103. 7020 V = V +1: IF V <10  THEN 7010
  104. 7030 V = V -1
  105. 7040  POKE 216,0: CALL 62248: RETURN 
  106. 8000  FOR I = 0 TO 116: READ BYTE: POKE 7936 +I,BYTE: NEXT : RETURN 
  107. 8010  DATA 162,0,173,3,64,133,226,173,4,64
  108. 8020  DATA 24,105,64,133,227,173,3,32,133,224
  109. 8030  DATA 173,4,32,24,105,32,133,225,165,226
  110. 8040  DATA 133,228,165,227,133,229,177,224,16,16
  111. 8050  DATA 145,226,230,224,208,2,230,225,230,226
  112. 8060  DATA 208,2,230,227,208,236,168,240,43,177
  113. 8070  DATA 224,201,47,208,1,136,152,129,226,177
  114. 8080  DATA 224,145,226,136,208,249,161,224,56,101
  115. 8090  DATA 224,133,224,144,2,230,225,161,226,56
  116. 8100  DATA 101,226,133,226,144,2,230,227,161,224
  117. 8110  DATA 48,182,129,226,168,208,218,165,227,201
  118. 8120  DATA 88,144,3,138,129,228,96